wikidata-2017-03-13 Graph

Description

Wikidata 2017-03-13 release

Infos

RDF triples	Subjects	Predicates	Objects	Time quota	Max results per request
2,262,175,283 triples	259,173,648	14,283	408,574,673	75ms	2000 bindings

VoID description

Access the VoID description of the RDF graph at http://soyez-sage.univ-nantes.fr/void/wikidata-2017-03-13

Query the RDF Graph

Graph URI: http://soyez-sage.univ-nantes.fr/sparql/wikidata-2017-03-13

Basic SPARQL queries

The SaGe server has a native support for evaluating a subset of the SPARQL syntax. It supports SPARQL queries with the following features:

Triple patterns
Basic Graph patterns
Unions
Filters, with simple expressions only (=, !=, <, >=, +, -, etc)
GRAPH clauses

Complete SPARQL 1.1 queries

To execute complete SPARQL queries using a SaGe server, you have two options:

Take a look at existing SaGe Smart Clients to evaluate SPARQL queries on your computer.
Use the online playground below

Example SPARQL queries

The following SPARQL queries can be executed on this RDF Graph.

Parents and their sons in Wikidata

FILTER

prefix wd: <http://www.wikidata.org/entity/>
prefix wdt: <http://www.wikidata.org/prop/direct/>
prefix wdno: <http://www.wikidata.org/prop/novalue/>
prefix rdf: <http://www.w3.org/1999/02/22-rdf-syntax-ns#>
prefix rdfs: <http://www.w3.org/2000/01/rdf-schema#>

SELECT ?person ?personLabel ?relative ?relativeLabel
WHERE
{
  ?person wdt:P40 ?relative ; # Find an entity with a relative
          wdt:P31 wd:Q5 ; # This entity must be an human
          rdfs:label ?personLabel .
  ?relative wdt:P21 wd:Q6581097; # The relative must be a male
            wdt:P31 wd:Q5 ; # This relative must be an human
            rdfs:label ?relativeLabel .
  FILTER(LANGMATCHES(LANG(?personLabel), "EN") && LANGMATCHES(LANG(?relativeLabel), "EN"))
}
LIMIT 10

Try this query

Madonna described by Wikidata

FILTER

prefix wd: <http://www.wikidata.org/entity/>
prefix schema: <http://schema.org/>
prefix rdfs: <http://www.w3.org/2000/01/rdf-schema#>

SELECT ?label ?description
WHERE
{
  wd:Q1744 rdfs:label ?label;
    	schema:description ?description.
  FILTER(LANGMATCHES(LANG(?label), LANG(?description)))
}

Try this query

Descendant of Johann Sebastian Bach (Property Path)

prefix rdfs: <http://www.w3.org/2000/01/rdf-schema#>
prefix wdt: <http://www.wikidata.org/prop/direct/>
prefix wd: <http://www.wikidata.org/entity/>

SELECT * WHERE {
    wd:Q1339 wdt:P40+ ?descendant.
    ?descendant rdfs:label ?name.
}

Try this query

Cats of Wikidata

FILTER

prefix wd: <http://www.wikidata.org/entity/>
prefix wdt: <http://www.wikidata.org/prop/direct/>
prefix schema: <http://schema.org/>
prefix rdfs: <http://www.w3.org/2000/01/rdf-schema#>

SELECT ?cat ?label ?description
WHERE
{
  ?cat wdt:P31 wd:Q146; # Find Cats
  	   rdfs:label ?label;
  	   schema:description ?description.
  FILTER(LANGMATCHES(LANG(?label), LANG(?description)))
}

Try this query

Siblings of Johan Sebastian Bach (Property Path)

prefix rdfs: <http://www.w3.org/2000/01/rdf-schema#>
prefix wdt: <http://www.wikidata.org/prop/direct/>
prefix wd: <http://www.wikidata.org/entity/>

SELECT * WHERE {
    wd:Q1339 wdt:P22/^wdt:P22 ?sibling.
    ?sibling rdfs:label ?name.
}

Try this query