dbpedia-2016-04 Graph

Description

DBpedia dataset v2016-04

Infos

RDF triples	Subjects	Predicates	Objects	Time quota	Max results per request
1,040,358,853 triples	58,167,851	68,687	206,201,072	75ms	2000 bindings

VoID description

Access the VoID description of the RDF graph at http://soyez-sage.univ-nantes.fr/void/dbpedia-2016-04

Query the RDF Graph

Graph URI: http://soyez-sage.univ-nantes.fr/sparql/dbpedia-2016-04

Basic SPARQL queries

The SaGe server has a native support for evaluating a subset of the SPARQL syntax. It supports SPARQL queries with the following features:

Triple patterns
Basic Graph patterns
Unions
Filters, with simple expressions only (=, !=, <, >=, +, -, etc)
GRAPH clauses

Complete SPARQL 1.1 queries

To execute complete SPARQL queries using a SaGe server, you have two options:

Take a look at existing SaGe Smart Clients to evaluate SPARQL queries on your computer.
Use the online playground below

Example SPARQL queries

The following SPARQL queries can be executed on this RDF Graph.

Famous people with the same name as a city

prefix dbo: <http://dbpedia.org/ontology/>
prefix rdfs: <http://www.w3.org/2000/01/rdf-schema#>

SELECT ?city ?person ?name
WHERE {
  ?city a dbo:City;
        rdfs:label ?name.
  ?person a dbo:Person;
        rdfs:label ?name.
}

Try this query

Desserts made with plants

prefix dbo: <http://dbpedia.org/ontology/>

SELECT ?dessert ?fruit
WHERE {
?dessert dbo:type <http://dbpedia.org/resource/Dessert>;
  dbo:ingredient ?fruit.
?fruit dbo:kingdom <http://dbpedia.org/resource/Plant>.
}

Try this query

Artists influenced by Picasso

prefix dbo: <http://dbpedia.org/ontology/>
prefix dbr: <http://dbpedia.org/resource/>

CONSTRUCT {
  ?artist a dbo:Artist.
  ?artist dbo:birthDate ?date.
}
WHERE {
  ?artist dbo:influencedBy dbr:Pablo_Picasso.
  ?artist a dbo:Artist.
  ?artist dbo:birthDate ?date.
}

Try this query

Artists born in York

OPTIONAL FILTER

prefix dbo: <http://dbpedia.org/ontology/>
prefix rdfs: <http://www.w3.org/2000/01/rdf-schema#>
prefix dbp: <http://dbpedia.org/property/>

SELECT ?name ?deathDate WHERE {
  ?person a dbo:Artist;
    rdfs:label ?name;
    dbo:birthPlace [ rdfs:label "York"@en ].
  FILTER LANGMATCHES(LANG(?name),  "EN")
  OPTIONAL { ?person dbp:dateOfDeath ?deathDate. }
}

Try this query

Directors of movies starring Brad Pitt

FILTER

prefix dbo: <http://dbpedia.org/ontology/>
prefix rdfs: <http://www.w3.org/2000/01/rdf-schema#>

SELECT ?movie ?title ?name WHERE {
?movie dbo:starring [ rdfs:label "Brad Pitt"@en ];
rdfs:label ?title;
dbo:director [ rdfs:label ?name ].
FILTER LANGMATCHES(LANG(?title), "EN")
FILTER LANGMATCHES(LANG(?name),  "EN")
}

Try this query

Award ceremonies in Dutch speaking countries

prefix dbo: <http://dbpedia.org/ontology/>
prefix dbp: <http://dbpedia.org/property/>
prefix dbr: <http://dbpedia.org/resource/>

SELECT ?award WHERE {
  ?award a dbo:Award;
    dbp:country [ dbo:language dbr:Dutch_language ].
}

Try this query

Actors married to movies

PREFIX rdfs: <http://www.w3.org/2000/01/rdf-schema#>
PREFIX dbo: <http://dbpedia.org/ontology/>

SELECT ?actor ?movie
WHERE {
	?x a dbo:Actor;
        rdfs:label ?actor;
        dbo:spouse ?y.
  	?y a dbo:Film;
      rdfs:label ?movie.
}

Try this query

Bands Michael Jackson wrote a song for

OPTIONAL FILTER

prefix dbo: <http://dbpedia.org/ontology/>
prefix dbr: <http://dbpedia.org/resource/>
prefix rdfs: <http://www.w3.org/2000/01/rdf-schema#>

SELECT DISTINCT ?performer ?name WHERE {
  ?work dbo:writer dbr:Michael_Jackson;
    dbo:musicalArtist ?performer.
  OPTIONAL {
    ?performer rdfs:label ?name.
    FILTER LANGMATCHES(LANG(?name), "EN")
  }
}

Try this query

Death causes of male American actors

prefix dbo: <http://dbpedia.org/ontology/>
prefix dc: <http://purl.org/dc/terms/>

SELECT ?actor ?cause
WHERE {
  ?actor dbo:deathCause ?cause.
  ?actor dc:subject <http://dbpedia.org/resource/Category:American_male_film_actors>
}

Try this query

Airports in Italy

prefix dbo: <http://dbpedia.org/ontology/>
prefix dbp: <http://dbpedia.org/property/>
prefix dbr: <http://dbpedia.org/resource/>

SELECT DISTINCT ?entity WHERE {
  ?entity a dbo:Airport;
    dbp:cityServed dbr:Italy.
}

Try this query

Authors of books

prefix dbo: <http://dbpedia.org/ontology/>
prefix rdf: <http://www.w3.org/1999/02/22-rdf-syntax-ns#>

SELECT DISTINCT ?book ?author
WHERE {
  ?book rdf:type dbo:Book;
    dbo:author ?author.
}
LIMIT 100

Try this query

Events that took place in the Trentino region

FILTER

prefix dbo: <http://dbpedia.org/ontology/>
prefix rdfs: <http://www.w3.org/2000/01/rdf-schema#>

SELECT DISTINCT ?entity ?event
WHERE {
  ?entity a dbo:Event;
    rdfs:label ?event;
    ?predicate <http://dbpedia.org/resource/Trentino> .
  FILTER(langMatches(lang(?event), "EN"))
}

Try this query

Foreign titles of Natalie Portman movies

SERVICE FILTER

PREFIX dbp: <http://dbpedia.org/property/>
PREFIX rdfs: <http://www.w3.org/2000/01/rdf-schema#>

SELECT ?titleEng ?title
WHERE {
  ?movie dbp:starring [ rdfs:label "Natalie Portman"@en ].
  SERVICE <http://sage.univ-nantes.fr/sparql/dbpedia-2015-04en> {
    ?movie rdfs:label ?titleEng, ?title.
  }
  FILTER LANGMATCHES(LANG(?titleEng), "EN")
  FILTER (!LANGMATCHES(LANG(?title), "EN"))
}

Try this query

Belgian Software

prefix dbo: <http://dbpedia.org/ontology/>
prefix rdfs: <http://www.w3.org/2000/01/rdf-schema#>

SELECT ?software ?company WHERE {
  ?software dbo:developer ?company.
  ?company dbo:locationCountry [ rdfs:label "Belgium"@en ].
}

Try this query